1、AC封挂微信验证全功能说明
① 微信验证功能说明
【运行原理】
1、玩家登录游戏--检测是不是绑定微信--未绑定（或已绑定微信，但是机器码有变更）--触发【AC反挂二密验证】，此时GM只需要将玩家传入等待验证的地图，或操作禁止交易买卖等锁定操作。
2、玩家绑定完微信（或验证完微信）--触发【AC反挂二密通过】，此时GM只需要将玩家传出验证地图，或操作解除一切负面锁定。
3、玩家在微信上直接发送解绑命令[查询绑定] 可以查看微信绑定的所有账号。再以绑定角色ID进行解除绑定 即 微信直接发送 [解除绑定 角色ID] 例如：解除绑定 6
【AC会调用四个指令】
4个命令分别在-M2-列表信息-其他列表-自定义命令列表
AC反挂二密验证 5
在对应的QF脚本内[@usercmd5] 触发进入监狱，禁止交易，禁止买卖等
发送 Sendmsg 5 【AC反挂需验证-<$INTS29>】 即发送验证请求。 Sendmsg 5 【AC反挂不需验证-<$INTS29>】 即发送验证请求且直接通过
AC反挂二密通过 6
在对应的QF脚本内[@usercmd6] 触发玩家验证通过，传送出去，同时解禁所有禁止的状态
AC反挂二密取消 7
在对应的QF脚本内[@usercmd7] 触发进入监狱，禁止交易，禁止买卖等
这个是玩家取消二密之后这个人就是未验证状态了 立即送往监狱小退再上也要在监狱了 直到 AC反挂二密通过 被调用
AC反挂拉黑 8
在对应的QF脚本内[@usercmd8] 触发进入锁定状态，提示微信ID被拉黑。
机器码：INTS 23
角色唯一标识：INTS 29
【UserCmd命令】 切记以下编号不能冲突占用，可以用蓝海变量查询筛选核实
AC反挂二密验证 5
AC反挂二密通过 6
AC反挂二密取消 7
AC反挂拉黑 8
【微信验证】切记以下INTS23 39不能冲突占用，可以用蓝海变量查询筛选核实
微信验证命令、脚本汇总：
自助解绑1：不需要验证直接强制解绑 Sendmsg 5 CMD=【AC反挂自助解绑】
自助解绑2：需要发送验证码，玩家自助解绑 Sendmsg 5 CMD=【AC反挂玩家解绑】
发起主动验证：Sendmsg 5 CMD=【AC反挂自助验证】
新上线或机器码不正确时需验证： Sendmsg 5 【AC反挂需验证-<$INTS29>】
机器码正确或满足条件时不验证： Sendmsg 5 【AC反挂不需验证-<$INTS29>】
解绑某个指定ID的角色：Sendmsg 5 CMD=【AC反挂自助解绑】|<$STR(SAC)>
[@自助解绑]
;隐藏微信验证图标使用NPC方式，玩家自助解绑时用
;需要发送验证码，玩家自助解绑
#IF
Compval <$INTS23> ! 0
#ACT
Sendmsg 5 CMD=【AC反挂玩家解绑】
[@强制解绑]
;脚本发起解绑命令，游戏里任意脚本执行，不需要验证直接强制解绑
#ACT
Sendmsg 5 CMD=【AC反挂自助解绑】
[@自助验证]
;脚本主动发起验证命令，游戏里任意脚本执行
;此时触发自动验证功能，0-10秒内弹出验证码验证框
;当验证通过时触发，QF自定命令 @AC反挂二密通过
;可用此配合自定脚本检测，比如进地图，当发起检测时传送玩家进入地图后，执行锁定人物不可移动攻击等等。
;当通过验证时执行解锁，此时可以做一个延迟执行30秒内，如果没有执行@AC反挂二密通过 段触发，说明未通过验证，可再次发起验证，直至通过
;详情可参考：自助发起验证防脱机举列.txt
#ACT
Sendmsg 5 CMD=【AC反挂自助验证】
[@解绑指定ID]
#if
Compval <$INTS23> = 5201314
#Act
Sendmsg 5 【AC反挂不需验证-<$INTS29>】
Mov SAC <$ints29>**********
Dec SAC 11 1000
INTS 23 = 0
INTS 29 = 0
MESSAGEBOX 尊敬的玩家你好，使用佣兵压卡后，角色转移成功，需要从新绑定新的微信号！\当前无法任何操作.请从新小退登录游戏
Sendmsg 5 CMD=【AC反挂自助解绑】|<$STR(SAC)>
QF内的：UserCmd5 UserCmd6 UserCmd7 UserCmd8脚本可以进行变通运用，自由发挥改造为你想要的个性化脚本！
② 如有商人发货脚本usercmd需要注意
;如果你使用的为老引擎，恰巧你版本有商人发货、自助交易之类的功能脚本。
;并且该脚本关联自定义USERCMD命令，或者自定义按钮，那么在脚本头必须做如下限制。
;最新的引擎可做可不做，因为新引擎lockdown类的锁定命令比较完备。保守起见可以都做起限制。
;2021年5月份之后新引擎用
#if(1)
Compval <$INTS23> = 0
Compval <$INTS23> ! <$HWIDLITE>
#Act
MessageBox 您还未进行微信验证，禁止操作！
Break
Close
;2021年5月份之前老引擎用
#IF
TRUE
#Act
MOV S1 <$HWIDLITE>
DEC S1 10 15
#if(1)
Compval <$INTS23> = 0
Compval <$INTS23> ! <$STR(S1)>
#Act
MessageBox 您还未进行微信验证，禁止操作！
Mov S1
Break
Close
③ 微信验证兼容佣兵契约脚本案例
;如果使用契约佣兵系统角色交易的GM记得添加新增如下脚本
;下方的INTS 23 29 如果你的版本没使用这个 请对应修改为你使用的INTS
;使用契约纸成功创建角色后执行的字段
[@NewCharByContractSuccess] 下增加
#if
true
#act
sendmsg 7 创角成功：正在使用契约创角的玩家：<$PARAMSTR(0)>，佣兵契约上的角色名：<$PARAMSTR(1)>，创建的新角色名：<$PARAMSTR(2)>
;StringsReplace 需要重命名的角色文本.txt <$PARAMSTR(1)> <$PARAMSTR(2)> 0 HardDisk
;创建的新角色名：<$PARAMSTR(2)>【设置23机器码为特殊值，表示为佣兵压卡操作】
Gmexecute INTS 23 <$PARAMSTR(2)> = 5201314
[@UserCmd5] 下第一行增加
#if
Compval <$INTS23> = 5201314
#Act
Sendmsg 5 【AC反挂不需验证-<$INTS29>】
Mov SAC <$ints29>**********
Dec SAC 11 1000
INTS 23 = 0
INTS 29 = 0
MESSAGEBOX 尊敬的玩家你好，使用佣兵压卡后，角色转移成功，需要从新绑定新的微信号！\当前无法任何操作.请从新小退登录游戏
Sendmsg 5 CMD=【AC反挂自助解绑】|<$STR(SAC)>
SetAbility 20 1 99999999
SetAbility 21 1 99999999
SetAbility 22 1 99999999
SetAbility 23 1 99999999
SetAbility 24 1 99999999
SetAbility 25 1 99999999
SetAbility 26 1 99999999
SetAbility 27 1 99999999
SetAbility 29 1 99999999
SetAbility 30 1 99999999
SetAbility 31 1 99999999
SetAbility 46 1 99999999
SetAbility 47 1 99999999
SetAbility 48 1 99999999
SetAbility 49 1 99999999
Lockdown 1
Break
④ 微信验证自助发起验证防脱机举列
;原理：可在任意要执行需要验证的脚本处执行此条 Sendmsg 5 CMD=【AC反挂自助验证】 即可实时发送验证
;可用于在地图打怪，以及回收脚本等，地图检测稍微简单只需要发起验证即可 回收等执行脚本相对麻烦下面举列回收脚本相关
[@需要执行段脚本XXXXX]
#IF
;防止玩家重复点击，发起验证
equal S验证结果 正在验证
#ACT
SENDMSG 7 亲爱的<$USERNAME>,当前正在验证中.请耐心等带10-30秒，无须重复点击
Break
;当玩家验证超时，再次发起验证，或者T下线
#IF
equal S验证结果 验证超时
#ACT
Sendmsg 5 CMD=【AC反挂自助验证】
DELAYGOTO 60000 @超时
SENDMSG 7 亲爱的<$USERNAME>,由于你的验证超时，现从新发起验证.请在60秒内处理验证
Break
#IF
;随机进行检测，如不需要可将RANDOM 30 删掉.数字越大越不容易验证，为避免频繁验证建议数字大些
RANDOM 30
equal S验证结果
#ACT
SetAbility 20 1 99999999
SetAbility 21 1 99999999
SetAbility 22 1 99999999
SetAbility 23 1 99999999
SetAbility 24 1 99999999
SetAbility 25 1 99999999
SetAbility 26 1 99999999
SetAbility 27 1 99999999
SetAbility 29 1 99999999
SetAbility 30 1 99999999
SetAbility 31 1 99999999
SetAbility 46 1 99999999
SetAbility 47 1 99999999
SetAbility 48 1 99999999
SetAbility 49 1 99999999
Lockdown 1
MOV S验证结果 正在验证
Sendmsg 5 CMD=【AC反挂自助验证】
SENDMSG 7 亲爱的<$USERNAME>,为了保障您的游戏权益，使用已关注本站众号微信重新验证.确认是您本人在使用.
SENDMSG 7 亲爱的<$USERNAME>,为了保障您的游戏权益，使用已关注本站众号微信重新验证.确认是您本人在使用.
SENDMSG 7 亲爱的<$USERNAME>,为了保障您的游戏权益，使用已关注本站众号微信重新验证.确认是您本人在使用.
DELAYGOTO 60000 @超时
Break
#IF(1)
equal S验证结果 验证通过
equal S验证结果
#ACT
CLEARDELAYGOTO
MOV S验证结果
SENDMSG 7 亲爱的<$USERNAME>,恭喜你验证通过.
#ELSEACT
MESSAGEBOX 错误原因如下：\请您先通过微信验证
BREAK
#IF
#ACT
;此处验证结果通过时，进行处理执行需要执行的脚本
[@超时]
#IF
!equal S验证结果 验证通过
#ACT
MOV S验证结果 验证超时
Break
#ELSEACT
;此处可自行跳转，也可让玩家在次点击NPC执行，当60秒后玩家没点NPC自动执行此段跳转回上段执行脚本
GOTO @需要执行段脚本XXXXX
BREAK
;此处是QFunction脚本内，CMD自定命令，通过验证时触发
[@UserCmd6]
#ACT
MOV S验证结果 验证通过
Ints 29 = <$PARAM(1)>
INTS 23 = <$HWIDLITE>
SetAbility 20 0 0
SetAbility 21 0 0
SetAbility 22 0 0
SetAbility 23 0 0
SetAbility 24 0 0
SetAbility 25 0 0
SetAbility 26 0 0
SetAbility 27 0 0
SetAbility 29 0 0
SetAbility 30 0 0
SetAbility 31 0 0
SetAbility 46 0 0
SetAbility 47 0 0
SetAbility 48 0 0
SetAbility 49 0 0
Lockdown 0
SENDMSG 7 %s，感谢您的配合，您已通过验证
Break
2、AC封挂实名认证全功能说明
【运行原理】
1、玩家登陆游戏--执行微信验证流程--达到指定条件触发【AC实名自助验证】，此时同步执行禁止交易买卖等锁定操作。
2、玩家输入姓名和身份证--发送到阿里云实名认证API校验--校验通过执行【AC实名认证通过】，此时同步执行解除一切负面锁定。
【AC会调用二个指令】
2个命令分别在-M2-列表信息-其他列表-自定义命令列表
AC实名认证通过 33
在对应的QF脚本内[@usercmd33] 触发实名验证通过，给予通过的个人标识，解除锁定状态。当玩家实名认证通过时，触发自定命令@AC实名认证通过
AC实名认证取消 34
在对应的QF脚本内[@usercmd34] 触发实名验证检测，未通过验证的进入强制锁定实名验证防沉迷状态。同时在微信管理端内解除实名的玩家也会触发此usercmd。当玩家实名认证取消时，触发自定命令@AC实名认证取消。
AC反挂游戏区名 35
在对应的QM登陆脚本首个玩家登陆时，指定当前区区名。
【UserCmd命令】 切记以下编号不能冲突占用，可以用蓝海变量查询筛选核实
AC实名认证通过 33
AC实名认证取消 34
AC反挂游戏区名 35
【实名验证脚本】切记以下INTS 个人标识[333]不能冲突占用，可以用蓝海变量查询筛选核实
自助解绑：不需要验证直接强制解绑 Sendmsg 5 CMD=【AC实名自助解绑】
自助验证：发起主动验证 Sendmsg 5 CMD=【AC实名自助验证】
[@需要验证]
;实名认证需要GM自由发起，程序并不会主动发起
;当需要发起实名认证时 脚本此时发起验证，程序接受到信息马上发起实名认证
#ACT
Sendmsg 5 CMD=【AC实名自助验证】
[@强制解绑]
;当角色交易或其他需要自助清空解绑实名信息时，只要发送以下内容即可立刻清理实名认证信息
#ACT
Sendmsg 5 CMD=【AC实名自助解绑】
【单独使用实名】
如客户不想使用微信验证，仅需要实名认证。可以在微信验证管理端里面打勾角色自动加白。（一般情况下不要勾选自动加白）
当实名，和微信一起使用时，自动白名单功能必须关闭！
3、AC封挂货币变量转区全功能说明
【运行原理】
1、玩家登陆游戏--功能脚本主动触发【AC反挂数据返回】进行微信端数据同步--基于唯一的微信ID，可以脚本发送或取回相应数字/字符串数据--脚本发送或取回时【AC反挂数据返回】均会同步返回相应执行结果。
2、基本操作流程， 增加-AC数据中心锁定账户-确定增加-AC数据中心返回增加结果-脚本收到结果执行解锁账户，如果异常失败3分钟自动解锁交易
3、此跨区变量跟随微信ID，不会因解绑、换号、换角色、合区、换区等各种情况丢失数据，免合区数据，支持跨区跨版本跨服务器保存数据。
4、可以基于此功能，实现多种货币跨服转区、跨服务器数据存储、跨版本签到、会员站包服卡、跨服务器装备转区等等个性化操作。
【AC会调用自定义命令】
命令在-M2-列表信息-其他列表-自定义命令列表
AC反挂数据返回 9
支持N个变量扩展 变量U开头是数字 T开头是字符串
整数类型储存 T开头变量 T后面2个中文固定格式或4个英文 如U元宝或英文Tyuan
脚本发送格式：其中变量【S转区AC】是增加元宝数量 【S转区领取AC】是领取微信中心储存的元宝数量
|货币名称|参数2(操作方式)|参数3(数值)|参数4(流水号)
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|查询数据量 -------仅查询数据 结果返回调用@usercmd9
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|获取流水号|增加 -------增加元宝至微信储存中心准备工作，此时将锁定账户不允许其他区操作数据 结果返回调用@usercmd9
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|增加|<$STR(S转区AC)>|<$PARAM(2)> -------确认增加元宝，AC中心处理增加，成功后结果返回调用@usercmd9
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|获取流水号|减少 -------减少微信储存中心元宝的准备工作，此时将锁定账户不允许其他区操作数据 结果返回调用@usercmd9
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|减少|<$STR(S转区领取AC)>|<$PARAM(2)> -------确认减少元宝，AC中心处理减少，成功后结果返回调用@usercmd9
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|解锁流水号|成功|<$PARAM(2)> -------执行成功加减元宝后，解锁微信中心账户锁定
字符串类型储存 T开头变量
|货币名称|参数2(操作方式)|参数3(数值)|参数4(流水号)|参数5(中文或英文字符串储存)
---注意字符串储存在参数5，当字符串储存时参数3数值写0即可，字符串只可储存修改和取回！
Sendmsg 5 CMD=【AC操作游戏数据】|T元宝|查询数据量 -------仅查询数据 结果返回调用@usercmd9
Sendmsg 5 CMD=【AC操作游戏数据】|T元宝|获取流水号|增加 -------增加元宝至微信储存中心准备工作，此时将锁定账户不允许其他区操作数据 结果返回调用@usercmd9
Sendmsg 5 CMD=【AC操作游戏数据】|T元宝|增加|0|<$PARAM(2)>|要储存的中文或英文 -------确认增加元宝，AC中心处理增加，成功后结果返回调用@usercmd9
Sendmsg 5 CMD=【AC操作游戏数据】|T元宝|解锁流水号|成功|<$PARAM(2)> -------执行成功加减元宝后，解锁微信中心账户锁定
AC返回格式：(第五位为OVER，作为判断数据的合法性) 【当字符串变量执行@AC反挂数据返回 查询结果 时，参数2返回的将是字符串储存的内容】
参数1 参数2 参数3 参数4 参数5 参数6 参数7 参数8
AC返回时执行 格式为： @AC反挂数据返回 查询结果 数量 第3位为*号 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝) 操作的微信ID
AC返回时执行 格式为： @AC反挂数据返回 流水号查询 16位流水号 增加 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝) 操作的微信ID
AC返回时执行 格式为： @AC反挂数据返回 流水号查询 16位流水号 减少 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝) 操作的微信ID
AC返回时执行 格式为： @AC反挂数据返回 增加OR减少 16位流水号 第3位为*号 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝) 操作的微信ID
基本操作流程， 增加-AC数据中心锁定账户-确定增加-AC数据中心返回增加结果-脚本收到结果执行解锁账户，如果异常失败3分钟自动解锁交易
[@MAIN]
测试通区数据元宝\\
<查询元宝/@z1> <增加元宝/@z2> <减少元宝/@z3>\\
<查询【元宝】字符串/@z4> <增加【元宝】字符串/@z5>
[@z1]
#act
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|查询数据量
; -------------------------------------------------------------查询结果返回调用 @usercmd9
; AC返回时执行 格式为： @AC反挂数据返回 查询结果 数量 第3位为*号 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝)
[@z2]
#IF
CheckLevelEx > 0
#ACT
MOV M42 0
Mov S转区AC
QUERYVALUE 42 1 10 @转区 请输入要转区的元宝
BREAK
[@转区]
#IF
LARGE M42 99
small M42 5000
#ACT
Mov S转区AC <$STR(M42)>**********
Dec S转区AC 11 1000
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|获取流水号|增加
; -------------------------------------------------------------结果返回调用 @usercmd9
; AC返回时执行 格式为： @AC反挂数据返回 流水号查询 16位流水号 增加 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝)
#ELSEACT
MESSAGEBOX 错误提示：\输入不能小于[100]...最底提现金额为100元\输入最大不能超过[5000]...
BREAK
[@z3]
#IF
CheckLevelEx > 0
#ACT
MOV M43 0
Mov S转区领取AC
QUERYVALUE 43 1 10 @转区领取 请输入要领取的元宝
BREAK
[@转区领取]
#IF
LARGE M43 99
small M43 5000
#ACT
Mov S转区领取AC <$STR(M43)>**********
Dec S转区领取AC 11 1000
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|获取流水号|减少
; -------------------------------------------------------------结果返回调用 @usercmd9
; AC返回时执行 格式为： @AC反挂数据返回 流水号查询 16位流水号 减少 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝)
#ELSEACT
MESSAGEBOX 错误提示：\输入不能小于[100]...最底提现金额为100元\输入最大不能超过[5000]...
BREAK
[@z4]
#act
Sendmsg 5 CMD=【AC操作游戏数据】|T元宝|查询数据量
; -------------------------------------------------------------查询结果返回调用 @usercmd9
; AC返回时执行 格式为： @AC反挂数据返回 查询结果 数量 第3位为*号 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝)
[@z5]
#IF
CheckLevelEx > 0
#ACT
MOV S42
QUERYVALUE 42 0 20 @数据储存 请输入要储存的内容
BREAK
[@数据储存]
#IF
!Compval <$STR(S42)> =
#ACT
Sendmsg 5 CMD=【AC操作游戏数据】|T元宝|获取流水号|增加
; -------------------------------------------------------------结果返回调用 @usercmd9
; AC返回时执行 格式为： @AC反挂数据返回 流水号查询 16位流水号 增加 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝)
#ELSEACT
MESSAGEBOX 错误提示：\输入的内容不能是空
BREAK
; QF执行段---------------------------
[@usercmd9]
; 检测过来的数据有没有微信的ID参数
#IF
Compval <$PARAM(4)> = ""
#ACT
BREAK
; 检测是不是操作失败了，并告诉玩家失败的原因
#IF
Compval <$PARAM(5)> = 失败
#ACT
MOV M43 0
MOV M42 0
MOV S42
Mov S转区AC
Mov S转区领取AC
MessageBox 转区失败，原因：/<$PARAM(6)>
Break
; 查询结果时货币的返回，领取微信中心元宝时，赋值S转区领取AC数据，用以比对玩家输入的领取数是不是小于微信中心储存数
#IF
Compval <$PARAM(1)> = 查询结果
#SAY
当前查询结果值为【<$PARAM(2)>】
#act
Break
; 〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓数字类增加
; 检测增加元宝时，人物身上元宝足不足够
#IF
CHECKGAMEGOLD < <$STR(M42)>
Compval <$PARAM(3)> = 增加
Compval <$PARAM(7)> = U元宝
#ACT
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|解锁流水号|失败|<$PARAM(2)>
MessageBox 转区失败，原因：/你身上的元宝不足【<$STR(M42)>】
BREAK
; 增加元宝时，不管成不成功，先扣除人物身上的元宝，然后通知AC中心操作增加(失败几率几乎等于0，除非微信中心未开启.未开启的情况下，也无法走到这一环节)
#IF
Compval <$PARAM(7)> = U元宝
Compval <$PARAM(1)> = 流水号查询
Compval <$PARAM(3)> = 增加
CHECKGAMEGOLD ? <$STR(M42)>
#ACT
GAMEGOLD - <$STR(M42)>
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|增加|<$STR(S转区AC)>|<$PARAM(2)>
; -------------------------------------------------------------此时我执行的格式为： CMD=【AC操作游戏数据】|U元宝|增加|数量|流水号
;执行完毕后你要返回给我结果 我要解锁账户可以继续执行
;AC返回时执行 格式为： @AC反挂数据返回 增加OR减少 16位流水号 第3位为*号 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝)
Break
; 〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓数字类减少
; 减少元宝，必须微信中心操作减少后，通知游戏内，此时可以给玩家增加，避免BUG出现，所以增加元宝是在返回成功时才增加，此时微信中心也已完成减少操作，保证数据一致
#IF
Compval <$PARAM(7)> = U元宝
Compval <$PARAM(1)> = 流水号查询
Compval <$PARAM(3)> = 减少
#ACT
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|减少|<$STR(S转区领取AC)>|<$PARAM(2)>
; -------------------------------------------------------------此时我执行的格式为： CMD=【AC操作游戏数据】|U元宝|减少|数量|流水号
;执行完毕后你要返回给我结果 我要解锁账户可以继续执行
;AC返回时执行 格式为： @AC反挂数据返回 增加OR减少 16位流水号 第3位为*号 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝)
Break
; 〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓字符串增加
; 增加字符串注意：参数5(中文或英文字符串储存) 当字符串储存时参数3数值写0即可
#IF
Compval <$PARAM(7)> = T元宝
Compval <$PARAM(1)> = 流水号查询
Compval <$PARAM(3)> = 增加
#ACT
Sendmsg 5 CMD=【AC操作游戏数据】|T元宝|增加|0|<$PARAM(2)>|<$STR(S42)>
; -------------------------------------------------------------此时我执行的格式为： CMD=【AC操作游戏数据】|T元宝|增加|0|流水号|要储存的中文或英文
;执行完毕后你要返回给我结果 我要解锁账户可以继续执行
;AC返回时执行 格式为： @AC反挂数据返回 增加OR减少 16位流水号 第3位为*号 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝)
Break
; 〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓返回的所有结果
; 当减少成功时，得到微信中心通知，才给玩家增加元宝，防止漏洞
#IF
Compval <$PARAM(7)> = U元宝
Compval <$PARAM(1)> = 减少
Compval <$PARAM(5)> = 成功
#ACT
GAMEGOLD + <$PARAM(3)>
MessageBox 转区成功，成功增加【<$PARAM(3)>】元宝
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|解锁流水号|成功|<$PARAM(2)>
MOV M43 0
MOV M42 0
Mov S转区AC
Mov S转区领取AC
Break
#IF
Compval <$PARAM(7)> = U元宝
Compval <$PARAM(1)> = 增加
Compval <$PARAM(5)> = 成功
#ACT
MessageBox 转区成功，你的账户扣除【<$STR(M42)>】元宝
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|解锁流水号|成功|<$PARAM(2)>
MOV M43 0
MOV M42 0
Mov S转区AC
Mov S转区领取AC
Break
#IF
Compval <$PARAM(7)> = T元宝
Compval <$PARAM(1)> = 增加
Compval <$PARAM(5)> = 成功
#ACT
MessageBox 储存成功，当前储存内容为【<$STR(S42)>】
Sendmsg 5 CMD=【AC操作游戏数据】|T元宝|解锁流水号|成功|<$PARAM(2)>
MOV M43 0
MOV M42 0
MOV S42
Mov S转区AC
Mov S转区领取AC
Break
|
