货币变量转区功能安装使用教程（所有引擎适用，需要8.9.5.3以后RunGate游戏网关和230904以后微信网关）
货币转区UT变量简介：支持跨服跨区变量操作功能，支持N个变量扩展，变量U开头是数字，T开头是字符串。如U元宝，U灵符。此跨区变量跟随微信ID，不会因解绑、换号、换角色、合区、换区等各种情况丢失数据，免合区数据，支持跨区跨版本跨服务器保存数据。可以基于此功能，实现多种货币跨服转区、跨服务器数据存储、跨版本签到、会员站包服卡、跨服务器装备转区等等个性化操作。微信验证管理端新增：转区流水界面，支持按条件、变量名、指定日期、指定区服、指定微信ID查询转区操作数据。
1、货币变量转区功能是基于微信验证模块，使用此功能的GM必须先根据上方教程，完整安装微信验证功能。
2、D:\MirServer\Mir200\Envir\UserCmd.txt 新增实名验证行为对应QF自定义命令
（usercmd编号不能和已有的冲突，可以用蓝海变量查询筛选核实）
AC反挂数据返回 9
复制代码
3、 D:\MirServer\Mir200\Envir\Market_Def\QFunction-0.txt 新增配套脚本
（usercmd编号不能和已有的冲突，可以用蓝海变量查询筛选核实）
[@usercmd9]
; 检测过来的数据有没有微信的ID参数
#IF
Compval <$PARAM(4)> = ""
#ACT
BREAK
; 检测是不是操作失败了，并告诉玩家失败的原因
#IF
Compval <$PARAM(5)> = 失败
#ACT
MOV M43 0
MOV M42 0
MOV S42
Mov S转区AC
Mov S转区领取AC
MessageBox 转区失败，原因：/<$PARAM(6)>
Break
; 查询结果时货币的返回，领取微信中心元宝时，赋值S转区领取AC数据，用以比对玩家输入的领取数是不是小于微信中心储存数
#IF
Compval <$PARAM(1)> = 查询结果
;#SAY
;当前查询结果值为【<$PARAM(2)>】
#act
MOV SAC剩余 <$PARAM(2)>
MOV S微信ID <$PARAM(4)>
Break
; 〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓数字类增加
; 检测增加元宝时，人物身上元宝足不足够
#IF
CHECKGAMEGOLD < <$STR(M42)>
Compval <$PARAM(3)> = 增加
Compval <$PARAM(7)> = U元宝
#ACT
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|解锁流水号|失败|<$PARAM(2)>
MessageBox 转区失败，原因：/你身上的元宝不足【<$STR(M42)>】
BREAK
; 增加元宝时，不管成不成功，先扣除人物身上的元宝，然后通知AC中心操作增加(失败几率几乎等于0，除非微信中心未开启.未开启的情况下，也无法走到这一环节)
#IF
Compval <$PARAM(7)> = U元宝
Compval <$PARAM(1)> = 流水号查询
Compval <$PARAM(3)> = 增加
CHECKGAMEGOLD ? <$STR(M42)>
#ACT
GAMEGOLD - <$STR(M42)>
SENDMSG 6 转区<$STR(M42)>元宝，扣除手续费，实际转出<$STR(M转区)>元宝
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|增加|<$STR(S转区AC)>|<$PARAM(2)>
; -------------------------------------------------------------此时我执行的格式为： CMD=【AC操作游戏数据】|U元宝|增加|数量|流水号
;执行完毕后你要返回给我结果 我要解锁账户可以继续执行
;AC返回时执行 格式为： @AC反挂数据返回 增加OR减少 16位流水号 第3位为*号 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝)
Break
; 〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓数字类减少
; 减少元宝，必须微信中心操作减少后，通知游戏内，此时可以给玩家增加，避免BUG出现，所以增加元宝是在返回成功时才增加，此时微信中心也已完成减少操作，保证数据一致
#IF
Compval <$PARAM(7)> = U元宝
Compval <$PARAM(1)> = 流水号查询
Compval <$PARAM(3)> = 减少
#ACT
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|减少|<$STR(S转区领取AC)>|<$PARAM(2)>
; -------------------------------------------------------------此时我执行的格式为： CMD=【AC操作游戏数据】|U元宝|减少|数量|流水号
;执行完毕后你要返回给我结果 我要解锁账户可以继续执行
;AC返回时执行 格式为： @AC反挂数据返回 增加OR减少 16位流水号 第3位为*号 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝)
Break
; 〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓字符串增加
; 增加字符串注意：参数5(中文或英文字符串储存) 当字符串储存时参数3数值写0即可
#IF
Compval <$PARAM(7)> = T元宝
Compval <$PARAM(1)> = 流水号查询
Compval <$PARAM(3)> = 增加
#ACT
Sendmsg 5 CMD=【AC操作游戏数据】|T元宝|增加|0|<$PARAM(2)>|<$STR(S42)>
; -------------------------------------------------------------此时我执行的格式为： CMD=【AC操作游戏数据】|T元宝|增加|0|流水号|要储存的中文或英文
;执行完毕后你要返回给我结果 我要解锁账户可以继续执行
;AC返回时执行 格式为： @AC反挂数据返回 增加OR减少 16位流水号 第3位为*号 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝)
Break
; 〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓〓返回的所有结果
; 当减少成功时，得到微信中心通知，才给玩家增加元宝，防止漏洞
#IF
Compval <$PARAM(7)> = U元宝
Compval <$PARAM(1)> = 减少
Compval <$PARAM(5)> = 成功
#ACT
GAMEGOLD + <$PARAM(3)>
MessageBox 转区成功，成功增加【<$PARAM(3)>】元宝
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|解锁流水号|成功|<$PARAM(2)>
MOV M43 0
MOV M42 0
MOV M手续 0
MOV M转区 0
Mov S转区AC
Mov S转区领取AC
Break
#IF
Compval <$PARAM(7)> = U元宝
Compval <$PARAM(1)> = 增加
Compval <$PARAM(5)> = 成功
#ACT
MessageBox 转区成功，你的账户扣除【<$STR(M42)>】元宝，存入微信账户<$STR(M转区)>元宝
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|解锁流水号|成功|<$PARAM(2)>
MOV M43 0
MOV M42 0
MOV M手续 0
MOV M转区 0
Mov S转区AC
Mov S转区领取AC
Break
#IF
Compval <$PARAM(7)> = T元宝
Compval <$PARAM(1)> = 增加
Compval <$PARAM(5)> = 成功
#ACT
MessageBox 储存成功，当前储存内容为【<$STR(S42)>】
Sendmsg 5 CMD=【AC操作游戏数据】|T元宝|解锁流水号|成功|<$PARAM(2)>
MOV M43 0
MOV M42 0
MOV S42
Mov S转区AC
Mov S转区领取AC
Break
复制代码
4、 D:\MirServer\Mir200\Envir\Market_Def\转区脚本-3.txt
（M42 M43变量不能和已有的冲突，可以用蓝海变量查询筛选核实）
#DEFINE $(最小转区金额) 1000
#DEFINE $(最大转区金额) 100000
#DEFINE $(转区手续费) 10 ←每次转区税率、百分比
[@MAIN]
#IF
TRUE
#ACT
SetMerchantDlgImgName
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|查询数据量
#SAY
<COLOR=#$0079FF 〝≈><COLOR=#$00A0FF Blue><COLOR=#$00B1FF Mir2.com><COLOR=#$00C2FF 出><COLOR=#$00D3FF 品><COLOR=#$00B1FF ≈><COLOR=#$00FFC5 正版><COLOR=#$00FFD6 授权
><COLOR=#$00FFE7 ≈><COLOR=#$00FFF8 公司><COLOR=#$00F5FF 运营><COLOR=#$00E4FF ≈><COLOR=#$00D3FF 独><COLOR=#$00C2FF 家><COLOR=#$00B1FF 奉><COLOR=#$00A0FF 献><COLOR=#$0079FF ≈
〞>\
<> <COLOR=#$00393942 ───────────────────────────>\
<> <COLOR=clLime 当前微 信ID:>【<$STR(S微信ID)>】 <刷新余额/@刷新>\\
<> <COLOR=clLime 当前账户剩余:>【<$STR(SAC剩余)>】元宝\
<> <COLOR=#$00393942 ───────────────────────────>\
<> <转区元宝/@z2> <COLOR=clMedGray 将元宝转到微信账户，转区手续费 (转区手续费)%>\\
<> <转入元宝/@z3> <COLOR=clMedGray 将元宝转入当前角色，转区$(最小转区金额)-$(最大转区金额)元宝>\\
[@刷新]
#IF
TRUE
#ACT
GOTO @main
[@z1]
#act
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|查询数据量
; -------------------------------------------------------------查询结果返回调用 @usercmd9
; AC返回时执行 格式为： @AC反挂数据返回 查询结果 数量 第3位为*号 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝)
[@z2]
#IF
CheckLevelEx > 0
#ACT
MOV M42 0
Mov S转区AC
QUERYVALUE 42 1 10 @转区 请输入要转区的元宝
BREAK
[@转区]
#IF
COMPVAL <$STR(M42)> ? $(最小转区金额)
!COMPVAL <$STR(M42)> > $(最大转区金额)
#ACT
MOV M手续 <$STR(M42)> $(转区手续费)
DIV M手续 100
MOV M转区 <$STR(M42)>
DEC M转区 <$STR(M手续)>
Mov S转区AC <$STR(M转区)>**********
Dec S转区AC 11 1000
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|获取流水号|增加
; -------------------------------------------------------------结果返回调用 @usercmd9
; AC返回时执行 格式为： @AC反挂数据返回 流水号查询 16位流水号 增加 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝)
#ELSEACT
MESSAGEBOX 错误提示：\输入不能小于[$(最小转区金额)]...\输入最大不能超过[$(最大转区金额)]...
BREAK
[@z3]
#IF
CheckLevelEx > 0
#ACT
MOV M43 0
Mov S转区领取AC
QUERYVALUE 43 1 10 @转区领取 请输入要领取的元宝
BREAK
[@转区领取]
#IF
COMPVAL <$STR(M43)> ? $(最小转区金额)
!COMPVAL <$STR(M43)> > $(最大转区金额)
#ACT
Mov S转区领取AC <$STR(M43)>**********
Dec S转区领取AC 11 1000
Sendmsg 5 CMD=【AC操作游戏数据】|U元宝|获取流水号|减少
; -------------------------------------------------------------结果返回调用 @usercmd9
; AC返回时执行 格式为： @AC反挂数据返回 流水号查询 16位流水号 减少 第4位为OVER 第5位成功与否 第6位错误原因 操作的变量名称(比如：U元宝或T元宝)
#ELSEACT
MESSAGEBOX 错误提示：\输入不能小于[$(最小转区金额)]...\输入最大不能超过[$(最大转区金额)]...
BREAK
|
